From 1c91be3ec65c185f5afe0ef37b390e533d1842e2 Mon Sep 17 00:00:00 2001
From: Andreas Zuber <a.zuber@gmx.ch>
Date: Sun, 21 Mar 2021 12:39:47 +0100
Subject: [PATCH] dev-python/hwi: bump to version 2.0.0

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Andreas Zuber <a.zuber@gmx.ch>
---
 dev-python/hwi/Manifest         |  1 +
 dev-python/hwi/hwi-2.0.0.ebuild | 56 +++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 dev-python/hwi/hwi-2.0.0.ebuild

diff --git a/dev-python/hwi/Manifest b/dev-python/hwi/Manifest
index 1365395f37..f33fc225c3 100644
--- a/dev-python/hwi/Manifest
+++ b/dev-python/hwi/Manifest
@@ -1 +1,2 @@
 DIST hwi-1.2.1.tar.gz 200755 BLAKE2B b426dcd78f0ff6039541b768155a0be11f591ee4e72957fce16ffd26841cd92c3e80ce57daefc531c31f912ec94139f53db8823a3fadf347f0153c1d47f1ad08 SHA512 b8cdda0ce9d4d9734e2754a47343fa7f331f55c609448561b1bed304629b6f01d80dadba55193633ad6ac1a8ba595f4574ae8aa32cfc841c34cbeff315310071
+DIST hwi-2.0.0.tar.gz 2777420 BLAKE2B d0285ad0cb2915dc0676e5f16476eb959c7ce6a79d6d5fd849bdcc58b71701025d32d3deadb824877ad8cb8d3f32572ac15df5d910b28269e8cf1fcbe322fa07 SHA512 515aa9df76f1a8759ebb154f833864968b9f381df721fe572e5a77570b38380268c35536abd2d232d5a0ab1f04a1a6b1db701c55f0379de0d1f3a691c789fd13
diff --git a/dev-python/hwi/hwi-2.0.0.ebuild b/dev-python/hwi/hwi-2.0.0.ebuild
new file mode 100644
index 0000000000..a2eb452546
--- /dev/null
+++ b/dev-python/hwi/hwi-2.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 udev
+
+DESCRIPTION="Library and command line tool for interacting with hardware wallets"
+HOMEPAGE="https://github.com/bitcoin-core/HWI"
+
+MY_PN="HWI"
+MY_P="${MY_PN}-${PV}"
+SRC_URI="https://github.com/bitcoin-core/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="udev doc"
+
+BDEPEND=""
+RDEPEND="
+	>=dev-python/bitbox02-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/ecdsa-0.13.0[${PYTHON_USEDEP}]
+	>=dev-python/hidapi-0.7.99[${PYTHON_USEDEP}]
+	>=dev-python/libusb1-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/mnemonic-0.18.0[${PYTHON_USEDEP}]
+	>=dev-python/pyaes-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.7.4.1[${PYTHON_USEDEP}]"
+
+distutils_enable_tests unittest
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# remove upper bounds on dependencies from setup.py file
+	sed 's/,<[0-9.]\+//' -i setup.py || die "sed failed"
+
+	pushd test
+	# remove tests that require hardware emulation
+	rm test_coldcard.py test_device.py test_digitalbitbox.py test_keepkey.py test_ledger.py test_trezor.py
+	# remove udev tests because it expects the rules are installed in the libs folder
+	rm test_udevrules.py
+	popd
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	use udev && udev_dorules hwilib/udev/*.rules
+	use doc  && dodoc -r docs
+
+	distutils-r1_python_install_all
+}