diff --git a/media-video/qliveplayer/Manifest b/media-video/qliveplayer/Manifest
index 8119f4ddb2..2a4e376bf7 100644
--- a/media-video/qliveplayer/Manifest
+++ b/media-video/qliveplayer/Manifest
@@ -1,2 +1,3 @@
 DIST QLivePlayer-3.22.1.tar.gz 640838 BLAKE2B 8552eefa4b8510b602e65fa553ba257467aaf5bd73710e90f690bcb19ceabc25dd4ae4f00143233df624f166f8170bf083aafbbec2d42e7988bd705037a9308e SHA512 45ec1f3d4d698a52107d07a7a55d457215d634b8106ac4facb9250960974f1ea683c338cedeb6f66fef428e88e05ef4286b3e95e22d23ed576c4bc69c5c7c50a
 DIST QLivePlayer-3.22.3.tar.gz 640956 BLAKE2B ed752d7321f90f70f68ab4366217116711b1f656eefc2f40b92572427dc11d168d2e9f88e6b0ba6c9e3024ede32922e06e04a208833858432e7ed923793b708d SHA512 c3ed5c8ffb4fa639132fdb0f42c20120a8e49c3e9135fe1234ec5eb6012e89a2e620ae4a3b669ecf995935c70f03fc154ca15833ff09ef6f83bba885e19e91a9
+DIST QLivePlayer-3.22.4.tar.gz 640975 BLAKE2B 313d6a68d9ab2914680e3c8f3478659fc8cae4e060f2006c0dba4441796c7880611ad1ca9d2d754bacd5cc542774eefcb0e46807b6dacc20a04c1538bda0394f SHA512 08fc3abb7b923baba09c60c86185431fe3754a1e06978247247e1482100e3b41c2a5185bc5fea1270fd2e7e9d90509880ea4ba4e8bb133cc4745f229c93744d3
diff --git a/media-video/qliveplayer/qliveplayer-3.22.4.ebuild b/media-video/qliveplayer/qliveplayer-3.22.4.ebuild
new file mode 100644
index 0000000000..ecc8b17527
--- /dev/null
+++ b/media-video/qliveplayer/qliveplayer-3.22.4.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit cmake optfeature python-single-r1 readme.gentoo-r1 xdg
+
+MY_P="QLivePlayer-${PV}"
+
+DESCRIPTION="A player and recorder for live streams and videos with danmaku support"
+HOMEPAGE="https://github.com/IsoaSFlus/QLivePlayer"
+SRC_URI="https://github.com/IsoaSFlus/QLivePlayer/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdeclarative-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtnetwork-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+	')
+	media-video/ffmpeg
+	media-video/mpv
+	net-misc/curl
+	>=dev-qt/qtquickcontrols-5.15:5
+	>=dev-qt/qtquickcontrols2-5.15:5
+	>=dev-qt/qtsvg-5.15:5
+"
+DEPEND="
+	${COMMON_DEPEND}
+	kde-frameworks/extra-cmake-modules:5
+"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+	# respect PYTHON_SINGLE_TARGET
+	grep 'p.start("python3", args);' src/qlphelper/bilivideo.cpp >/dev/null || die
+	sed -i "s/python3/${EPYTHON}/" src/qlphelper/bilivideo.cpp || die
+	grep 'dmcPyProcess->start("python3", dmcPy);' \
+		src/qlphelper/danmakulauncher.cpp >/dev/null || die
+	sed -i "s/python3/${EPYTHON}/" src/qlphelper/danmakulauncher.cpp || die
+	grep 'proc->start("python3", args);' \
+		src/qlphelper/streamfinder.cpp >/dev/null || die
+	sed -i "s/python3/${EPYTHON}/" src/qlphelper/streamfinder.cpp || die
+}
+
+src_install() {
+	cmake_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+	optfeature "twitch support" "net-misc/streamlink"
+	optfeature "youtube support" "dev-python/protobuf-python net-misc/streamlink"
+}