dev-libs/open62541: add 1.4.10

Signed-off-by: Kurt Kanzenbach <kurt@kmk-computers.de>

dev-libs/open62541/Manifest

@@ -1 +1,2 @@
+DIST open62541-1.4.10.tar.gz 4217021 BLAKE2B 9ef247a61c0feb49d66d1125f6007cab8d6ad21505ea62d2bcaf2230dcd53ac5de6f23b33f46fe3a809fda25658051be7cc435a9e56566e570716156b92a10e1 SHA512 d5124eeb6e5083ab1aa015379568975bfee4ba295e49fb6728dcd9899455e71f8cad00c6e9ee8cbea8b2f9452484c773b0d82ff28700a316c3d3c7fd62ebeec6
 DIST open62541-1.4.9.tar.gz 4216977 BLAKE2B 01de57a86be3fdbb1a09f9ff2026349f229c74c4d73fa688e355f63d2bba0780fc888df06504ad7f2fb42baf85a8b71ff7c13c11df3f9c1b6d1535028e5b4bf7 SHA512 cd1f3bcd681f349a4c80872c23aaa60591101982cae2d353f28ce5f3200f067f793b298290c451c1d3b2c3580a8baaca405ece40c3521617effcddb28e27606f

dev-libs/open62541/open62541-1.4.10.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="Open source C implementation of OPC UA"
+HOMEPAGE="https://www.open62541.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples mbedtls pubsub openssl tools"
+# Requires network access
+RESTRICT="test"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	?? ( mbedtls openssl )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? (
+		media-gfx/graphviz
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="
+	mbedtls? ( net-libs/mbedtls:= )
+	openssl? ( dev-libs/openssl:0= )
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DOPEN62541_VERSION=v${PV}
+		-DUA_BUILD_EXAMPLES=OFF
+		-DUA_BUILD_TOOLS=$(usex tools)
+		-DUA_BUILD_UNIT_TESTS=OFF
+		-DUA_ENABLE_HARDENING=OFF
+		-DUA_ENABLE_PUBSUB=$(usex pubsub)
+		-DUA_ENABLE_PUBSUB_INFORMATIONMODEL=$(usex pubsub)
+		-DUA_FORCE_WERROR=OFF
+	)
+
+	use mbedtls && mycmakeargs+=(-DUA_ENABLE_ENCRYPTION=MBEDTLS)
+	use openssl && mycmakeargs+=(-DUA_ENABLE_ENCRYPTION=OPENSSL)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_build doc
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${WORKDIR}"/${P}_build/doc/. )
+	cmake_src_install
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples/
+	fi
+}
+
+src_test() {
+	cmake_src_test -j1
+}