gui-apps/intiface-central-bin: add 2.6.0

Signed-off-by: tea <gentoo@tastytea.de>

gui-apps/intiface-central-bin/Manifest

@@ -1 +1,2 @@
 DIST intiface-central-v2.5.7-linux-ubuntu-22.04-x64.zip 19978864 BLAKE2B 0e22f90eaf464fae0463f31a6a1537154956c44e04a91514aca2f097c4f2494d802b1e40e762b2e7f639efaf142b9fed56384fe5d1e167afba39132678554049 SHA512 be855842b3150e7e9f972502dc2711051528305419c135c525ac3d2d5b5002e1c923d91fee9d533e170f05d29bc0047e2772b8e10ba8373c10eb7d4ce034e4eb
+DIST intiface-central-v2.6.0-linux-ubuntu-22.04-x64.zip 19506920 BLAKE2B 751c4cfe4f6c543614d6724ee7292579d4b0532f1656c5dd8a13d9d19293327dc2c460f06e6d940bc2b6ea2a3fae2aa26cbe99e786237996210b0d0684acbfbc SHA512 acaf49792926bfc267da67f89f3f54a79e3c848d5b90ff2bc1eb9f166379df967af8623c79360743f42b6d9d3c3ad5c03430809b462b4b088e94e00e65e8d807

gui-apps/intiface-central-bin/intiface-central-bin-2.6.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop xdg
+
+DESCRIPTION="Buttplug frontend application"
+HOMEPAGE="https://github.com/intiface/intiface-central"
+SRC_URI="https://github.com/intiface/intiface-central/releases/download/v${PV}/intiface-central-v${PV}-linux-ubuntu-22.04-x64.zip"
+S="${WORKDIR}/${PN/-bin/}-v${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	app-accessibility/at-spi2-core
+	dev-libs/glib
+	dev-libs/openssl:0/3
+	media-gfx/graphite2
+	media-libs/harfbuzz
+	sys-apps/dbus
+	sys-apps/systemd-utils
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[X]
+	x11-libs/pango
+"
+BDEPEND="app-arch/unzip"
+
+QA_PREBUILT="
+	opt/${PN}/lib/*.so
+	opt/${PN}/intiface_central
+"
+
+src_install() {
+	insinto /opt/${PN}
+	doins -r .
+	fperms +x /opt/${PN}/intiface_central
+
+	cat << EOF > intiface_central
+#!/bin/sh
+cd /opt/${PN}
+./intiface_central "\${@}"
+EOF
+	dobin intiface_central
+
+	newicon --size 512 \
+		data/flutter_assets/assets/icons/intiface_central_icon.png ${PN}.png
+
+	make_desktop_entry intiface_central "Intiface Central" ${PN} "Utility"
+}