dev-python/rich-click: add 1.8.9

Signed-off-by: jan Anja (cybertailor) <cyber+gentoo@sysrq.in>

dev-python/rich-click/rich-click-1.8.9.ebuild

@@ -0,0 +1,41 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} pypy3_11 )
+
+inherit click-app distutils-r1
+
+DESCRIPTION="Format click help output nicely with rich"
+HOMEPAGE="
+	https://pypi.org/project/rich-click/
+	https://github.com/ewels/rich-click
+"
+SRC_URI="https://github.com/ewels/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/click-7[${PYTHON_USEDEP}]
+	>=dev-python/rich-10.7[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+click-app_enable_completions rich-click
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	touch tests/fixtures/__init__.py || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}