diff --git a/dev-lang/hare/Manifest b/dev-lang/hare/Manifest
index 99652eb91c..e765e5f5f9 100644
--- a/dev-lang/hare/Manifest
+++ b/dev-lang/hare/Manifest
@@ -1 +1,2 @@
 DIST hare-0.24.2.tar.gz 912808 BLAKE2B 2dbb83448efe85c36be50ebfbe9c8c567ac7a8c420253f242aa911e815fbf41ff4fbe0e36d22b5654b74441cc73bbaac9de5b9cdb06f9f687813babe2bf359c0 SHA512 6214d0068f507f156bff85d12aeb515e5f752bff03645b3b207d224aecc62e34d4a44a171fc2b357eaaf72a804c2b79d6ad2886caa2804f1dcad07cc25d7efac
+DIST hare-0.25.2.tar.gz 940391 BLAKE2B 626b098a4a65c1a8760dc75317dd856f03915d564800beaa6c8708726bfd602c291d5e449139922293a3af087fa7ed2e9076e76e2e2731cab5908256d00894b5 SHA512 a72bda105c3bb40c0d43382f10030883d84d2b3511197890a4641eacfc84cbcf8f5aa15391d31e5b04b2e3154f5db0d7d855d08d213f9cd089ad536cbabdcec5
diff --git a/dev-lang/hare/hare-0.25.2.ebuild b/dev-lang/hare/hare-0.25.2.ebuild
new file mode 100644
index 0000000000..4ef0d76a9c
--- /dev/null
+++ b/dev-lang/hare/hare-0.25.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ "${PV}" = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/hare"
+	SLOT="0"
+else
+	MY_PV="$(ver_rs 3 -)"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://git.sr.ht/~sircmpwn/hare/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	SLOT="0/${PV}"
+	KEYWORDS="~amd64 ~arm64 ~riscv"
+fi
+
+DESCRIPTION="The Hare systems programming language"
+HOMEPAGE="https://harelang.org/"
+LICENSE="MPL-2.0 GPL-3"
+
+# release policy: https://git.sr.ht/~sircmpwn/hare/tree/master/item/docs/release.md
+DEPEND="
+	~dev-lang/harec-0.24.2
+	>=sys-devel/qbe-1.2
+"
+BDEPEND="app-text/scdoc"
+RDEPEND="${DEPEND}"
+
+# hare and haredoc are built by hare
+QA_FLAGS_IGNORED="usr/bin/hare usr/bin/haredoc"
+
+src_configure() {
+	local target_arch
+	case ${ARCH} in
+		amd64 ) target_arch=x86_64 ;;
+		arm64 ) target_arch=aarch64 ;;
+		riscv ) target_arch=riscv64 ;;
+		* ) die "unsupported architecture: ${ARCH}" ;;
+	esac
+
+	# Note: PREFIX needs to be set early as it is used for HAREPATH
+	cp configs/linux.mk config.mk || die
+	sed -i \
+		-e "s;^ARCH =.*;ARCH = ${target_arch};" \
+		-e "s;^PREFIX =.*;PREFIX = ${EPREFIX}/usr;" \
+		-e 's;^AS =;AS ?=;' \
+		-e 's;^LD =;LD ?=;' \
+		-e 's;^AR =;AR ?=;' \
+		config.mk || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+}