From 0f46c242323b2e6f56cf3d4f316707c8534335f5 Mon Sep 17 00:00:00 2001
From: "Haelwenn (lanodan) Monnier" <contact@hacktivis.me>
Date: Sat, 21 Jun 2025 17:06:29 +0200
Subject: [PATCH] dev-lang/harec: add 0.25.2

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
---
 dev-lang/harec/Manifest            |  1 +
 dev-lang/harec/harec-0.25.2.ebuild | 43 ++++++++++++++++++++++++++++++
 2 files changed, 44 insertions(+)
 create mode 100644 dev-lang/harec/harec-0.25.2.ebuild

diff --git a/dev-lang/harec/Manifest b/dev-lang/harec/Manifest
index 8735aecc29..ec1a93c5bf 100644
--- a/dev-lang/harec/Manifest
+++ b/dev-lang/harec/Manifest
@@ -1 +1,2 @@
 DIST harec-0.24.2.tar.gz 201789 BLAKE2B b7241fc9e3265486982104fad4d21323a591642b7c19edbedaa4f8b299ed9cde8412b0ef95b0faf33fa8aa6153dc5f965199d5778a434823f8c6faabcd38fde3 SHA512 3b32e82df937de1fdd2af20a2162bc3754cb9178cd67e56f3e7bc7fc9eb9e9bad5609ca1c328d42ac5cdd527edf6d9c381dc384df72c2d7666c7ce5684871a17
+DIST harec-0.25.2.tar.gz 205091 BLAKE2B 9d6c1e208ef9ab35f56fa0974741f3eadae59b1f8ea1fbe42b012cde827adfd5c7a84336e3f0e94d4ad69cf975f02d930f3bc88c5f6584ad9334f6cfdb3fdd07 SHA512 227fe4879a4c367e6cdbf85efc43797db012cce74fcaf30e08cc1ec49014ac426eadace650d2d566a9eb629a6bc87bf739613c1c1360dbf5d47b1aa51195cb9a
diff --git a/dev-lang/harec/harec-0.25.2.ebuild b/dev-lang/harec/harec-0.25.2.ebuild
new file mode 100644
index 0000000000..b215ee6dd5
--- /dev/null
+++ b/dev-lang/harec/harec-0.25.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+if [[ "${PV}" = "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/harec"
+else
+	MY_PV="$(ver_rs 3 -)"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://git.sr.ht/~sircmpwn/harec/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64 ~arm64 ~riscv"
+fi
+
+DESCRIPTION="The Hare compiler"
+HOMEPAGE="https://harelang.org/"
+LICENSE="GPL-3"
+SLOT="0"
+
+DEPEND=">=sys-devel/qbe-1.2"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	cp configs/linux.mk config.mk || die
+	sed -i \
+		-e 's/-Werror//' \
+		-e 's/CC =/CC ?=/' \
+		-e 's/AS =/AS ?=/' \
+		-e 's/LD =/LD ?=/' \
+		config.mk || die
+
+	tc-export CC AS LD
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+}