From 0eb3655b884d6fc786e6fa99e35ca364e5f73073 Mon Sep 17 00:00:00 2001
From: Paul Zander <negril.nx+gentoo@gmail.com>
Date: Mon, 30 Jun 2025 10:14:25 +0200
Subject: [PATCH] x11-drivers/evdi: drop 1.14.10

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
---
 x11-drivers/evdi/Manifest            |  1 -
 x11-drivers/evdi/evdi-1.14.10.ebuild | 83 ----------------------------
 2 files changed, 84 deletions(-)
 delete mode 100644 x11-drivers/evdi/evdi-1.14.10.ebuild

diff --git a/x11-drivers/evdi/Manifest b/x11-drivers/evdi/Manifest
index 79ece035bf..df47438168 100644
--- a/x11-drivers/evdi/Manifest
+++ b/x11-drivers/evdi/Manifest
@@ -1,2 +1 @@
-DIST evdi-1.14.10.tar.gz 97166 BLAKE2B 67e489a3287d773262997cb16337293979fbbfe01b7e32de0dbdf1ab95bcfc25e08707d5fdb44a735a561579b2888d7578761051e78ec34dc76429eb261519ff SHA512 3937af9a2cc377f505c45de4ad0c28c778ef91ee7157341dfe411c8c1dde6c665cede26963678b7492688338059dd57f7fe296666e439240eb0f4d478bafbc28
 DIST evdi-1.14.9.tar.gz 97080 BLAKE2B 85dd5543bcc9ff94e69a6e9c2c5bc36748bd62ec5f55dee71831c37369c231d71548610547d74e8d307cf2b32b4117f40c0948edccc3e32f4a35a5203e027e18 SHA512 55d1d424ae637436b5f5937df6dbbb14bc02b4d7b2e8ce24002494d4a935466637987a188b74a7bc6b9f4eeb417dd60a471eceee85d0fd440901a5153a323fe2
diff --git a/x11-drivers/evdi/evdi-1.14.10.ebuild b/x11-drivers/evdi/evdi-1.14.10.ebuild
deleted file mode 100644
index f4105664f4..0000000000
--- a/x11-drivers/evdi/evdi-1.14.10.ebuild
+++ /dev/null
@@ -1,83 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{11..13} )
-inherit linux-mod-r1 python-single-r1 flag-o-matic
-
-DESCRIPTION="Extensible Virtual Display Interface"
-HOMEPAGE="https://github.com/DisplayLink/evdi"
-SRC_URI="https://github.com/DisplayLink/evdi/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2 LGPL-2.1"
-SLOT="0/$(ver_cut 1)"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-
-IUSE="python test"
-
-RDEPEND="${PYTHON_DEPS}
-	python? (
-		$(python_gen_cond_dep '
-			dev-python/pybind11[${PYTHON_USEDEP}]
-			test? (
-				dev-python/pytest-mock[${PYTHON_USEDEP}]
-			)
-		')
-	)
-"
-
-DEPEND="${RDEPEND}
-	x11-libs/libdrm
-	sys-kernel/linux-headers
-"
-
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-RESTRICT="!test? ( test )"
-
-# module/Kconfig
-CONFIG_CHECK="~FB_VIRTUAL ~I2C ~DRM ~USB_SUPPORT ~USB_ARCH_HAS_HCD MODULES"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-1.14.4-format-truncation.patch"
-)
-
-pkg_setup() {
-	linux-mod-r1_pkg_setup
-	use python && python-single-r1_pkg_setup
-}
-
-src_compile() {
-	filter-lto
-
-	local modlist=(
-		"evdi=video:module"
-	)
-	local modargs=(
-		CONFIG_DRM_EVDI="m" # https://github.com/DisplayLink/evdi/issues/476
-		KVER="${KV_FULL}"
-		KDIR="${KV_OUT_DIR}"
-	)
-	linux-mod-r1_src_compile
-
-	emake -C library
-
-	use python && emake -C pyevdi
-}
-
-src_test() {
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-
-	use python && emake -C pyevdi tests
-}
-
-src_install() {
-	linux-mod-r1_src_install
-
-	local -x DESTDIR="${ED}" PREFIX="${EPREFIX}"
-
-	LIBDIR="/usr/$(get_libdir)" emake -C library install
-
-	use python && emake -C pyevdi install
-}