dev-util/osc: fixup ebuild

-removed symlink
-tests need config file, so restricted
-move keywords into first if statement
-cleanup inherit line
-fix indentation
-quote unquoted variable

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>

dev-util/osc/osc-0.169.1.ebuild

@@ -5,66 +5,62 @@ EAPI=7
 
 PYTHON_COMPAT=( python3_{6,7,8} )
 PYTHON_REQ_USE="xml"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="Command line tool for Open Build Service"
+HOMEPAGE="https://en.opensuse.org/openSUSE:OSC https://github.com/openSUSE/osc"
 
 if [[ "${PV}" == "9999" ]]; then
 	EGIT_REPO_URI="https://github.com/openSUSE/${PN}.git"
-	EXTRA_ECLASS="git-r3"
+
+	inherit git-r3
 else
-	SRC_URI="https://github.com/openSUSE/${PN}/archive/${PV}.tar.gz"
+	SRC_URI="https://github.com/openSUSE/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 	OBS_PROJECT="openSUSE:Tools"
+
+	KEYWORDS="~amd64 ~x86"
 fi
 
-DISTUTILS_SINGLE_IMPL=1
-inherit distutils-r1 ${EXTRA_ECLASS}
-unset EXTRA_ECLASS
-
-DESCRIPTION="Command line tool for Open Build Service"
-HOMEPAGE="https://en.opensuse.org/openSUSE:OSC"
-
 LICENSE="GPL-2"
 SLOT="0"
-IUSE=""
 
-# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
-[[ "${PV}" == "9999" ]] || \
-KEYWORDS="~amd64 ~x86"
+# Test require config file: osc.oscerr.NoConfigfile
+RESTRICT="test"
 
 RDEPEND="
 	app-arch/rpm[python,${PYTHON_SINGLE_USEDEP}]
-  $(python_gen_cond_dep '
-	  dev-python/m2crypto[${PYTHON_USEDEP}]
-  ')
+	$(python_gen_cond_dep '
+		dev-python/m2crypto[${PYTHON_USEDEP}]
+	')
 	${PYTHON_SINGLE_DEPS}
 "
 
 BDEPEND="
-        $(python_gen_cond_dep '
-          >=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
-        ')
-        test? (
-                ${RDEPEND}
-                $(python_gen_cond_dep '
-                  dev-python/path-py[${PYTHON_USEDEP}]
-                ')
-        )
-"
+	$(python_gen_cond_dep '
+		>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	')
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/path-py[${PYTHON_USEDEP}]
+	')
+)"
 
 distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-}
+# Bug: https://bugs.gentoo.org/704520
+#distutils_enable_sphinx docs dev-python/alabaster
 
 src_install() {
 	distutils-r1_src_install
+
 	dosym osc-wrapper.py /usr/bin/osc
-	rm -f "${ED}"/usr/share/doc/${PN}*/TODO*
+	rm -f "${ED}/usr/share/doc/${PN}"*/TODO*
 	insinto /usr/share/bash-completion/completions
 	newins dist/complete.sh osc
 	insinto /usr/lib/osc
 	newins dist/osc.complete complete
 	insinto /usr/share/zsh/site-functions
-	newins ${FILESDIR}/osc.zsh_completion _osc
+	newins "${FILESDIR}/osc.zsh_completion" _osc
 }
-
-# vim:set sts=2 ts=2 sw=2 et: