From 0cb1cc664bd83f4b6980e70b0d0172569a3f11de Mon Sep 17 00:00:00 2001
From: David Roman <stkw0@disroot.org>
Date: Tue, 24 Mar 2026 17:13:18 +0100
Subject: [PATCH] dev-python/pytest-steps: remove dependency on mkdocs

Signed-off-by: David Roman <stkw0@disroot.org>
---
 .../pytest-steps/pytest-steps-1.8.0-r1.ebuild | 54 +++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dev-python/pytest-steps/pytest-steps-1.8.0-r1.ebuild

diff --git a/dev-python/pytest-steps/pytest-steps-1.8.0-r1.ebuild b/dev-python/pytest-steps/pytest-steps-1.8.0-r1.ebuild
new file mode 100644
index 0000000000..5c3da08f32
--- /dev/null
+++ b/dev-python/pytest-steps/pytest-steps-1.8.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Create step-wise / incremental tests in pytest"
+HOMEPAGE="
+	https://pypi.org/project/pytest-steps/
+	https://github.com/smarie/python-pytest-steps
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/makefun-1.5[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=( "${FILESDIR}/${P}-strict-mkdocs.patch" )
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( ${PN} pytest-cases pytest-harvest pytest-xdist )
+EPYTEST_DESELECT=(
+	# tests fail with recent Pandas
+	pytest_steps/tests/test_docs_example_with_harvest.py::test_synthesis_df
+	pytest_steps/tests/test_steps_harvest.py::test_synthesis
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed "/pytest-runner/d" -i setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest pytest_steps/tests --doctest-modules
+}