net-irc/srain: add 1.6.0

Closes: https://bugs.gentoo.org/887863
Closes: https://bugs.gentoo.org/897638
Signed-off-by: Christopher Byrne <salah.coronya@gmail.com>

net-irc/srain/Manifest

@@ -1 +1,2 @@
 DIST srain-1.4.0.tar.gz 1935950 BLAKE2B 7d3db119bcc07ccb427850530e551f643e202d3f2f276c8b347324f99474e57052368b8eed52e74ba6403a47b3bd4b7842ee007d9035bbba8e69beba8e3be9e6 SHA512 1708d1d1ec97c9f35a8702526a95bb60bf0ea50b742a76081508ef42a512e8c113ef1949c3b9f3db4585d8fb11cdb197f65fc7bc10480a533c69982c21185e55
+DIST srain-1.6.0.tar.gz 2760635 BLAKE2B 18676142c875b9715cd3e94b9877e6ae7235e035299284dc410b7ae6be26eb01450557da0c9cb050d71d79145583132601f12a395c28968b23361f84c1f08fce SHA512 59d962ddbf71724d5f68decc1e3b873cea6c6bd2ca23b21a1a6fe937d53f2871398fdcda906840755efc6b454d2d5116ca620c047f1634fb68b45ab2c0443a57

net-irc/srain/srain-1.6.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+inherit meson python-any-r1 xdg
+
+DESCRIPTION="Modern, beautiful IRC client written in GTK+ 3"
+HOMEPAGE="https://github.com/SrainApp/srain"
+SRC_URI="https://github.com/SrainApp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="appindicator doc man"
+
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/glib:2
+	dev-libs/libconfig:=
+	dev-libs/openssl:=
+	net-libs/libsoup:2.4
+	x11-libs/gtk+:3
+	appindicator? ( dev-libs/libayatana-appindicator )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( $(python_gen_any_dep '
+		dev-python/sphinx[${PYTHON_USEDEP}]' ) )
+	man? ( $(python_gen_any_dep '
+		dev-python/sphinx[${PYTHON_USEDEP}]' ) )
+	${PYTHON_DEPS}
+"
+
+python_check_deps() {
+	if use doc || use man; then
+		python_has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed "s/\('doc'\), meson.project_name()/\1, '${PF}'/" \
+		-i meson.build || die
+}
+
+src_configure() {
+	local -a doc_builders=()
+	use doc && doc_builders+=( html )
+	use man && doc_builders+=( man )
+
+	local emesonargs=(
+		-Ddoc_builders="$(meson-format-array "${doc_builders[@]}")"
+		$(meson_use appindicator app_indicator)
+	)
+	meson_src_configure
+}