app-misc/fastfetch: add 1.6.4

Signed-off-by: Viorel Munteanu <ceamac.paragon@gmail.com>

app-misc/fastfetch/Manifest

@@ -1,2 +1,3 @@
 DIST fastfetch-1.6.1.tar.gz 349168 BLAKE2B 21076a879e921898766d70566f21cbf9d3f05a6dfc8b2b32be8908f32e0b130c01aca43b1c61ea5fb909757eca116e8bdb604f65d695a7b40b40f18607452597 SHA512 f0a5609cf8d3b57331617396f1c9656ac41dbcb58f485cc6a035dcc02813d7888d7ba42ee953d7f6bc1dd5c3a1ca702f6d1a8582ad5c6b8a4d085f1d40ac3c85
 DIST fastfetch-1.6.3.tar.gz 350035 BLAKE2B ca15d18455d889ffe7a5448977f64504eb0c503f81c9d0c276fa6940c668f93e937add5cdda20f37285b9eb7b8974c34b5d3a15eeac6da3b96470c38c04fd6c4 SHA512 04d4dd2850e104b2938bce13a1e3fd93ab1c18676bff9ba3e9524a762ead000c7b3707d530aaad718f1b01723dc749d2f74343a64fb932474098115aadba3665
+DIST fastfetch-1.6.4.tar.gz 350947 BLAKE2B 4fd493c15f6997fbb4caa6ce3a4266addc2a8f1fcb6328cdbfbc24988ca7d778bcdd1d3f8ba21894436a0a6aca83ea3a8396de43016c5b66ec55bc9148062222 SHA512 7470ab66ef3a0a351f3455240625fdffc04f487fd9af6975fcbb4ba5803357bfab55156c7b6396faab3d12b26b883a0c0eb8722b23f08173250d51527949b30d

app-misc/fastfetch/fastfetch-1.6.4.ebuild

@@ -0,0 +1,88 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? (
+		media-gfx/chafa
+		media-gfx/imagemagick:=
+	)
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_ZLIB=yes
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_DBUS=$(usex dbus)
+	)
+
+	cmake_src_configure
+}

app-misc/fastfetch/fastfetch-9999.ebuild

@@ -46,27 +46,19 @@ RDEPEND="
 DEPEND="${RDEPEND}"
 BDEPEND="virtual/pkgconfig"
 
-REQUIRED_USE="xrandr? ( X )"
+REQUIRED_USE="
-
+	xrandr? ( X )
-pkg_setup() {
+	chafa? ( imagemagick )
-	if use chafa && ! use imagemagick; then
+"
-		elog "USE chafa depends on imagemagick, but that is currently disabled.  Enabling imagemagick"
-	fi
-
-	if use imagemagick || use chafa; then
-		export fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-	else
-		export fastfetch_enable_imagemagick7=no
-	fi
-
-	if use imagemagick || use chafa; then
-		export fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-	else
-		export fastfetch_enable_imagemagick6=no
-	fi
-}
 
 src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
 	local mycmakeargs=(
 		-DENABLE_RPM=no
 		-DENABLE_LIBPCI=$(usex pci)