diff --git a/sys-apps/lact/Manifest b/sys-apps/lact/Manifest
index 0d34a85952..d4e5f6edcd 100644
--- a/sys-apps/lact/Manifest
+++ b/sys-apps/lact/Manifest
@@ -1,2 +1,4 @@
 DIST lact-0.9.0-crates.tar.xz 30886548 BLAKE2B 223575f0a478cda107e788798764c77a8ceac753d74b8af769f5804d019650242414855a713c94d571f61c163100c592b8efb2ee0cce811cb194174241b32703 SHA512 529c47f136eb2e2bf35980bb27ec1b80816afee6bfa971db4a944240ebf56ca9f153491d44901c24a91049b78d57f94262a73c31573e20a24baf40369bf96a57
 DIST lact-0.9.0.tar.gz 4507549 BLAKE2B aacf68315c66bf7425ed33e77abd267153a28c1ab2f856cda4b38ec58f49f195dbf7402a8246897dfc65888d21a49d6a220780f50e084b92f4b215714b2e0d45 SHA512 7090095972e6c14b379a481f099285abb8ef6f088e91fdb43e3309a0f4d603bddbf28b2ae1d1d65fe31094f687dbb40e2c1e097d826e3fa4778420349fc3f929
+DIST lact-0.9.1-crates.tar.xz 30943484 BLAKE2B 820445b5ae44bc9a98c39ce0a7ec28e81f3b510c989b71b8a61ea42b039a64dc60d3dcd2f76421e4154fd8513c684fb6d91c931f0b465870b21f931fc0a61562 SHA512 d9c93eef3e96a71e24aea0d3bf7d38971d72cb43fe2878579ff5b620f712920dd149bf58f7587496ed46c29834eeb56f4ddd53fda120918f61583cd0df84842e
+DIST lact-0.9.1.tar.gz 4645570 BLAKE2B ecd55d75124ead52212f1efe1ecc4de40a857994c2dc5ced381ec4d2132bb9f8df157ff73a7b539784b4a76a385ebdc04089a35fb0ecde04201c32c37533e450 SHA512 1dd3fbaacd3b8a252286f9c2ad7a831316438fd701ed049aa3889e39a636d3e747c503422f28a53e13bea2ab9ca482edaecc46cc81a26b542f3111594490fc3d
diff --git a/sys-apps/lact/lact-0.9.1.ebuild b/sys-apps/lact/lact-0.9.1.ebuild
new file mode 100644
index 0000000000..205eef11a3
--- /dev/null
+++ b/sys-apps/lact/lact-0.9.1.ebuild
@@ -0,0 +1,101 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+
+LLVM_COMPAT=( {19..22} )
+RUST_MIN_VER="1.93.0"
+
+inherit cargo llvm-r2 xdg
+
+DESCRIPTION="Linux GPU Control Application"
+HOMEPAGE="https://github.com/ilya-zlobintsev/LACT"
+SRC_URI="
+	https://github.com/ilya-zlobintsev/LACT/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://github.com/pastalian/distfiles/releases/download/${P}/${P}-crates.tar.xz
+	"
+fi
+S="${WORKDIR}/${P^^}"
+
+LICENSE="MIT"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD CC0-1.0
+	CDLA-Permissive-2.0 ISC LGPL-3+ MIT MPL-2.0 Unicode-3.0 ZLIB
+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gui test video_cards_nvidia"
+REQUIRED_USE="test? ( gui )"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	!test? ( x11-libs/libdrm )
+	test? ( x11-libs/libdrm[video_cards_amdgpu,video_cards_intel] )
+	gui? (
+		dev-libs/glib:2
+		gnome-base/gsettings-desktop-schemas
+		gui-libs/gtk:4[introspection]
+		>=gui-libs/libadwaita-1.5.0:1
+		media-libs/graphene
+		media-libs/libdisplay-info:=
+		x11-libs/cairo
+		x11-libs/pango
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	dev-util/clinfo
+	dev-util/vulkan-tools
+	sys-apps/hwdata
+"
+DEPEND="
+	${COMMON_DEPEND}
+	test? ( sys-fs/fuse:3 )
+"
+# libclang is required for bindgen
+BDEPEND="
+	virtual/pkgconfig
+	$(llvm_gen_dep 'llvm-core/clang:${LLVM_SLOT}')
+"
+
+QA_FLAGS_IGNORED="usr/bin/lact"
+
+pkg_setup() {
+	llvm-r2_pkg_setup
+	rust_pkg_setup
+}
+
+src_configure() {
+	local myfeatures=(
+		$(usev gui lact-gui)
+		$(usev gui display-info)
+		$(usev video_cards_nvidia nvidia)
+	)
+	cargo_src_configure --no-default-features
+}
+
+src_compile() {
+	cargo_src_compile -p lact
+}
+
+src_install() {
+	cargo_src_install --path lact
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install-resources
+	newinitd res/lact-daemon-openrc lactd
+}
+
+src_test() {
+	local CARGO_SKIP_TESTS=(
+		# requires /dev/fuse access
+		tests::apply_settings
+	)
+	cargo_src_test --workspace
+}