media-gfx/bambustudio-bin: add 01.10.01.50

Signed-off-by: Huang Rui <vowstar@gmail.com>

media-gfx/bambustudio-bin/Manifest

@@ -1 +1,2 @@
 DIST bambustudio-bin-01.10.00.89.AppImage 112932032 BLAKE2B 1924afb881e6159207775fbb255639d4f5decc52add4acdfd74e847f398c55b901ff375cdbbe5937e414e87f9e1e3bcea1c95d542d200f3f8dd4c165a7b22634 SHA512 3539c22c569298479781dfa5f0a74504d2471397e02dfa5fca3e1d65365b95585f1161182c5004be3793ac732f5d1d94bb6659bc3c5fb20aeb699733894ea71f
+DIST bambustudio-bin-01.10.01.50.AppImage 112915648 BLAKE2B ed1b569037d46f8e73f02571317e213e504088fdb4a202e6d3a5a82cc49451819a43ce8bd5bdc73700057c381019bdd42ba1cf86400d4483ddb108f08dc2a70e SHA512 a6ccfebe9349b189ccb6457c7e9aa3df0a3f0a2c42839fc0cd6a7fee2245a08e8c1acdfe556e772f9d20761ed7838f23c8ef3841537daa2e469438ce74072be3

media-gfx/bambustudio-bin/bambustudio-bin-01.10.01.50.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="BambuStudio"
+WX_GTK_VER="3.0-gtk3"
+
+inherit desktop wrapper xdg
+
+DESCRIPTION="Bambu Studio is a cutting-edge, feature-rich slicing software"
+HOMEPAGE="https://bambulab.com"
+
+SRC_URI="
+	https://github.com/bambulab/${MY_PN}/releases/download/v${PV}/Bambu_Studio_linux_fedora-v${PV}.AppImage \
+	-> ${P}.AppImage
+"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+RDEPEND="
+	media-gfx/openvdb
+	media-libs/glew:0=
+	>=media-libs/glm-0.9.9.1
+	media-libs/gstreamer
+	media-libs/mesa[X(+)]
+	net-libs/libsoup:3.0=
+	net-libs/webkit-gtk:4.1/0
+	>=sci-libs/opencascade-7.3.0:0=
+	virtual/glu
+	>=x11-libs/cairo-1.8.8:=
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.30
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl]
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/patchelf
+"
+
+QA_PREBUILT="*"
+RESTRICT="strip"
+
+src_unpack() {
+	mkdir "${S}" || die
+	cp "${DISTDIR}/${P}.AppImage" "${S}"/ || die
+	pushd "${S}" || die
+	chmod +x "${S}/${P}.AppImage" || die
+	"${S}/${P}.AppImage" --appimage-extract || die
+	rm "${S}/${P}.AppImage" || die
+	popd || die
+}
+
+src_install() {
+	rm -r squashfs-root/{*.{AppImage,desktop},.DirIcon,usr} || die
+	patchelf --replace-needed libwebkit2gtk-4.0.so.37 libwebkit2gtk-4.1.so.0 \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	patchelf --replace-needed libjavascriptcoregtk-4.0.so.18 libjavascriptcoregtk-4.1.so.0 \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	patchelf --remove-needed libsoup-2.4.so.1 \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	patchelf --set-rpath '$ORIGIN' \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	insinto /opt/"${PN}"
+	doins -r "${S}"/squashfs-root/*
+	fperms +x "/opt/${PN}/AppRun" "/opt/${PN}/bin/bambu-studio"
+	doicon -s 192 "${S}"/squashfs-root/BambuStudio.png
+	domenu "${FILESDIR}/bambu-studio.desktop"
+	make_wrapper bambu-studio "/opt/${PN}/AppRun"
+}