dev-python/proton-vpn-network-manager: new package, add 0.12.13

Signed-off-by: Mattéo Rossillol‑‑Laruelle <beatussum@protonmail.com>

dev-python/proton-vpn-network-manager/Manifest

@@ -0,0 +1 @@
+DIST proton-vpn-network-manager-0.12.13.tar.gz 60323 BLAKE2B 59e73fcd8554f1fc3bb1f44c684f53001584b991651655eb85660ff41b3cf72e538e9f88335c7b73ba2f3721b988dcad9071efb326499001fd86dc050beed327 SHA512 6c48f260b5d819885d89ffe6d40060764c2ea95efc5eec19cd5b4bf614c2cc4f449158c816593c9e93f4ffcda285691ce04cd64bce360404a0ddd5a98d92637a

dev-python/proton-vpn-network-manager/metadata.xml

@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+	<maintainer type="person">
+		<email>beatussum@protonmail.com</email>
+		<name>Mattéo Rossillol‑‑Laruelle</name>
+	</maintainer>
+
+	<stabilize-allarches/>
+
+	<upstream>
+		<maintainer status="active">
+			<name>Proton AG</name>
+			<email>opensource@proton.me</email>
+		</maintainer>
+
+		<bugs-to>https://github.com/ProtonVPN/python-proton-vpn-network-manager/issues/</bugs-to>
+		<remote-id type="github">ProtonVPN/python-proton-vpn-network-manager</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/proton-vpn-network-manager/proton-vpn-network-manager-0.12.13.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 linux-info
+
+DESCRIPTION="Proton VPN Network Manager handler"
+HOMEPAGE="https://github.com/ProtonVPN/python-proton-vpn-network-manager"
+SRC_URI="https://github.com/ProtonVPN/python-proton-vpn-network-manager/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/python-${P}"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-python/pytest-asyncio[${PYTHON_USEDEP}] )"
+
+RDEPEND="
+	dev-python/jinja2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/proton-core[${PYTHON_USEDEP}]
+	dev-python/proton-vpn-api-core[${PYTHON_USEDEP}]
+	dev-python/proton-vpn-local-agent[${PYTHON_USEDEP}]
+	dev-python/pygobject[${PYTHON_USEDEP}]
+	net-misc/networkmanager[introspection]
+	net-vpn/networkmanager-openvpn
+"
+
+CONFIG_CHECK="~DUMMY ~WIREGUARD"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -i "/--cov/d" setup.cfg || die
+}
+
+python_test() {
+	XDG_RUNTIME_DIR="${T}/python_test" epytest
+}