# Copyright 2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..11} )

PYPI_NO_NORMALIZE=1
PYPI_PN="${PN/-/\.}"
inherit distutils-r1 pypi

DESCRIPTION="This package provides a flexible test runner with layer support."
HOMEPAGE="https://github.com/zopefoundation/zope.testrunner"

LICENSE="ZPL"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	dev-python/six[${PYTHON_USEDEP}]
	dev-python/zope-interface[${PYTHON_USEDEP}]
	dev-python/zope-exceptions[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinxcontrib-programoutput[${PYTHON_USEDEP}] )
	test? ( dev-python/zope-testing[${PYTHON_USEDEP}] )
"
DEPEND="${RDEPEND}"

distutils_enable_sphinx docs
distutils_enable_tests unittest

src_prepare() {
	# strip rdep specific to namespaces
	sed -i -e "/'setuptools'/d" setup.py || die
	distutils-r1_src_prepare
}

python_compile() {
	distutils-r1_python_compile
	find "${BUILD_DIR}" -name '*.pth' -delete || die
}

python_test() {
	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
	distutils_write_namespace zope
	eunittest
}

python_install() {
	# Do not install unit tests
	rm -r "${BUILD_DIR}/install$(python_get_sitedir)/zope/testrunner/tests" || die
	distutils-r1_python_install
}
