# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit unpacker xdg

DESCRIPTION="A beautiful, fast and fully open source mail client for Mac, Windows and Linux"
HOMEPAGE="https://getmailspring.com/"
SRC_URI="
	amd64? ( https://github.com/Foundry376/Mailspring/releases/download/${PV}/mailspring-${PV}-amd64.deb )
	arm64? ( https://github.com/Foundry376/Mailspring/releases/download/${PV}/mailspring-${PV}-arm64.deb )
"
S="${WORKDIR}"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="+wayland"

RDEPEND="
	app-accessibility/at-spi2-core:2
	app-crypt/mit-krb5
	app-text/htmltidy
	dev-build/libtool
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/nspr
	dev-libs/nss
	dev-libs/openssl
	gnome-base/gvfs
	media-libs/alsa-lib
	media-libs/mesa
	net-misc/curl
	net-print/cups
	sys-apps/dbus
	sys-libs/db:5.3
	x11-libs/cairo
	x11-libs/gtk+:3
	x11-libs/libX11
	x11-libs/libxcb
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libxkbcommon
	x11-libs/libXrandr
	x11-libs/pango
	x11-misc/xdg-utils
"

QA_PREBUILT="*"

src_unpack(){
	unpack_deb ${A}
}

src_prepare(){
	default
	if use wayland; then
		sed -i "s|Exec=mailspring %U|Exec=mailspring --ozone-platform-hint=auto --enable-wayland-ime %U|g" \
			"${S}/usr/share/applications/Mailspring.desktop" || die
	fi

	mv "${S}/usr/share/doc/mailspring" "${S}/usr/share/doc/${PF}" || die
	mv "${S}/usr/share/appdata" "${S}/usr/share/metainfo" || die
}

src_install(){
	cp -R "${S}"/* "${D}" || die "Installing binary files failed"
}
