# Copyright 2022-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

if [[ "${PV}" = "9999" ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/himitsu-ssh"
else
	SRC_URI="https://git.sr.ht/~sircmpwn/himitsu-ssh/archive/${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
fi

DESCRIPTION="SSH integration for Himitsu"
HOMEPAGE="https://git.sr.ht/~sircmpwn/himitsu-ssh"
LICENSE="GPL-3"
SLOT="0"

RDEPEND="
	>=app-admin/himitsu-0.10:=
	>=dev-hare/hare-ssh-0.26.0:=
"
DEPEND="
	${RDEPEND}
	>=dev-lang/hare-0.26.0:=
"
BDEPEND="app-text/scdoc"

# All binaries are hare-built
QA_FLAGS_IGNORED=".*"

src_configure() {
	sed -i 's;^PREFIX=.*;PREFIX=/usr;' Makefile || die

	tc-export AS LD CC AR
}

src_test() {
	# Don't run tests if there's none (which is the case of 0.3)
	grep -r '@test fn' . && emake check
}
